Move tmux-sessionizer configuration

modules2/hosts/t480/tmux-sessionizer.nix

@@ -0,0 +1,15 @@
+{
+  flake.modules.homeManager.base =
+    { config, ... }:
+    {
+      programs.tmux-sessionizer.searchPaths =
+        let
+          inherit (config.xdg) userDirs;
+        in
+        [
+          "${userDirs.extraConfig.XDG_REPOS_DIR}:2"
+          "${userDirs.documents}:1"
+          "${config.home.homeDirectory}/tmp"
+        ];
+    };
+}

modules2/tmux-sessionizer/config.nix

@@ -0,0 +1,26 @@
+{ lib, ... }:
+
+{
+  flake.modules.homeManager.base =
+    { config, ... }:
+    {
+      options.programs.tmux-sessionizer = {
+        searchPaths = lib.mkOption {
+          default = [ config.home.homeDirectory ];
+          type = lib.types.listOf lib.types.str;
+          description = "List of search paths for tmux-sessionizer to use.";
+        };
+
+        # TODO: add TS_EXTRA_SEARCH_PATHS.
+        # TODO: add TS_MAX_DEPTH.
+        # TODO: add TS_SESSION_COMMANDS once I figure out what they're for.
+      };
+
+      config = {
+        xdg.configFile."tmux-sessionizer/tmux-sessionizer.conf".text = ''
+          TS_SEARCH_PATHS=(${builtins.concatStringsSep " " config.programs.tmux-sessionizer.searchPaths})
+          TS_SESSION_COMMANDS=(nvim .)
+        '';
+      };
+    };
+}

modules2/tmux-sessionizer/default.nix

@@ -0,0 +1,30 @@
+{
+  flake.modules.homeManager.base =
+    { config, pkgs, ... }:
+    {
+      home.file.".tmux-sessionizer".source = "${
+        pkgs.writeShellApplication {
+          name = ".tmux-sessionizer";
+
+          runtimeInputs = with pkgs; [
+            tmux
+          ];
+
+          text = ''
+            set +o errexit
+            set +o nounset
+
+            if [[ "$PWD" == "${config.xdg.userDirs.extraConfig.XDG_REPOS_DIR}/os" || "$PWD" == "${config.xdg.userDirs.extraConfig.XDG_REPOS_DIR}/personal" || "$PWD" == "${config.xdg.userDirs.extraConfig.XDG_REPOS_DIR}/work"  ]]; then
+              clear
+
+              return
+            fi
+
+            tmux new-window -d -n scratch
+            nvim .
+            clear
+          '';
+        }
+      }/bin/.tmux-sessionizer";
+    };
+}

modules2/tmux-sessionizer/package.nix

@@ -0,0 +1,7 @@
+{
+  flake.modules.homeManager.base =
+    { pkgs, ... }:
+    {
+      home.packages = with pkgs; [ tmux-sessionizer ];
+    };
+}